Felipe Rotilho

Pie Chart - Facade para o Google Charts

2010-08-01T14:30:00.012-03:00

Bom, resolvi desenvolver um facade para o google chart, está super simples de entender. Espero adicionar mais gráficos com o tempo além de dar maior suporte aos principais recursos do GoogleChart.

Exemplo de Uso:

Sub Initialize()
 Dim pie As New Pie(500, 200)
 
 Dim pieSlice As New PieSlice("Felipe","100")
 Call pie.addSlice(pieSlice)
 Set pieSlice = New PieSlice("Rotilho","200")
 Call pie.addSlice(pieSlice)
 Set pieSlice = New PieSlice("FelipeRotilho","150")
 Call pie.addSlice(pieSlice)
 Call pie.setChartType("p3")
 
 Print pie.getURL()
End Sub

Source Code:

Const errNotImplemented = 13001
Const googleChartURL = "http://chart.apis.google.com/chart?"
%REM
 Class Chart
 Description: Chart class monta um link do Google Chart
 Atualizado no dia 2, de Agosto de 2010.
%END REM
Class Chart
 Private chartType As String
 
 %REM
  Sub setChartType
  Description: Types: p, p3 e pc
 %END REM
 Public Sub setChartType(strType As String)
  chartType = "cht=" + strType + |&|
 End Sub
 
 %REM
  Function getChartType
  Description: Comments for Function
 %END REM
 Public Function getChartType As String
  getChartType = chartType
 End Function
 
 %REM
  Function getURL
  Description: Retorna URL do Google Chart
 %END REM
 Public Function getURL As String
  Error errNotImplemented, "Function não implementada"
 End Function
 
End Class

%REM
 Class Pie
 Description: Comments for Class
%END REM
Class Pie As Chart
 Private x As String
 Private y As String
 Private index As Integer
 Private slices() As PieSlice
 %REM
  Sub New
  Description: Constructor
 %END REM
 Public Sub New(x As Double, y As Double)
  Me.x = CStr(x)
  Me.y = CStr(y)
  Call Me.setChartType("p3")
 End Sub
 
 %REM
  Function getURL
  Description: Comments for Function
 %END REM
 Public Function getURL As String
  Dim link As String
  link = googleChartURL
  link = link + Me.getChartType()
  link = link + Me.getChartSize()
  link = link + Me.getValues()
  link = link + Me.getLabels()
  getURL = link
 End Function
 
 %REM
  Sub addSlice
  Description: Comments for Sub
 %END REM
 Public Sub addSlice(pieSlice As PieSlice)
  Set slices(nextPosition) = pieSlice
 End Sub
 
 
 %REM
  Function getValues
  Description: Comments for Function
 %END REM
 Public Function getValues As String
  Dim values As String
  values = "chd=t:"
  
  Dim i As Integer
  For i = 0 To index - 1
   values = values + slices(i).getValue()
   If i < (index - 1) Then
    values = values + "," 
   End If
  Next
  getValues = values + |&|
 End Function
 
 %REM
  Function getLabels
  Description: Comments for Function
 %END REM
 Public Function getLabels As String
  Dim labels As String
  labels = |chl=|
  
  Dim i As Integer
  For i = 0 To index - 1
   labels = labels + slices(i).getLabel()
   If i < (index - 1) Then
    labels = labels + "|"
   End If
  Next
  getLabels = labels + |&|
 End Function
 
 
 %REM
  Function nextPosition
  Description: Comments for Function
 %END REM
 Private Function nextPosition As Integer
  ReDim Preserve slices(index)
  nextPosition = index
  index = index + 1
 End Function
 
 %REM
  Function getChartSize
  Description: Comments for Function
 %END REM
 Private Function getChartSize As String
  getChartSize = |chs=| +CStr(x) + |x| + CStr(y) + |&|
 End Function
 
End Class

%REM
 Class PieSlice
 Description: Slice of Pie
%END REM
Class PieSlice
 Private label As String
 Private value As String
 %REM
  Sub New
  Description: Comments for Sub
 %END REM
 Public Sub New(label As String, value As String)
  Me.label = label
  Me.value = value
 End Sub
 
 %REM
  Function getLabel
  Description: Comments for Function
 %END REM
 Public Function getLabel As String
  getLabel = label
 End Function
 
 %REM
  Function getValue
  Description: Comments for Function
 %END REM
 Public Function getValue As String
  getValue = value
 End Function
End Class

Transferindo documentos para outras database

2010-07-31T12:40:00.002-03:00

Recentemente fiz uma migração de uma aplicação legado em Clipper para NSF, só que perdia muito tempo no I/O. Para contornar este problema optei por utilizar threads, tendo um ganho significativo de performance. Durante a resolução deste problema criei um Connector que se encarregava da transferir os documents.

Connector: RotilhoConnector.jar 2k
Atualizado no dia 1, de Agosto de 2010.

Segue um exemplo de sua utilização:

import edu.rotilho.RotilhoConnector;
import lotus.domino.Database;
import lotus.domino.DocumentCollection;
import lotus.domino.NotesException;

public class TransferCollection implements Runnable{ 
 private DocumentCollection documentCollection;
 private Database targetDatabase;
 public TransferCollection(DocumentCollection documentCollection, Database targetDatabase){
  this.documentCollection = documentCollection;
  this.targetDatabase = targetDatabase;
 }
 public void run() {
  RotilhoConnector con = new RotilhoConnector(){
   public Database getDatabase() {
    return targetDatabase;
   }
  };
  try {
   con.copyToDatabase(documentCollection);
  } catch (NotesException e) {
   e.printStackTrace();
  }
 }
}

O método copyToDatabase aceita como parâmetro Document, DocumentCollection, ViewEntry, ViewEntryCollection, Database e View,

Parando de Adaptar a Roda - Lotus (Agora) Sabe

2010-07-30T21:47:00.000-03:00

"Não reinvente a roda" é o que sempre costumo ouvir, entretanto me deparo constantemente com situações onde é necessário estudar a roda de uma outra plataforma e simular o seu funcionamento, seja por limitações da versão do Lotus Notes que utilizo (6.5 / 2003) ou da própria API. Porém, o que mais me deixa de cabelo branco são algumas limitações do próprio LotusScript, tendo que muitas vezes escrever um código não tão bom quanto poderia ser simplesmente por não poder utilizar, por exemplo, interfaces.

Estes problemas, limitações da linguagem, são facilmente contornados com o Java. A IBM logo teve esta sacada, porém demorou a apresentar uma IDE a altura, consequentemente o LotusScript acabou virando o jogador principal da maioria das aplicações no mercado enquanto o Java aguardou no banco de reservas.

Com o lançamento do 8.5 percebi que a comunidade como um todo se empolgou, uma lista a perder de vista de novas funcionalidade enchem a boca de qualquer desenvolvedor Lotus Notes, mas o que mais me animou foi a nova IDE, muito mais robusta e intuitiva.

Como será o Lotus Notes 9? ;)

Sorting Collection

2010-07-30T17:59:00.006-03:00

Exemplo de uso:

Private Function getAllRecursos As String
  Dim html As String
  Dim col As NotesDocumentCollection
  Dim doc As NotesDocument
  
  Set col = p.getAllRecursos
  Dim sc As New SortCollection(col, col.Parent)
  Call sc.addCampo("dataDistribuicao")
  Set col = sc.Sort
  
  Set doc = col.GetFirstDocument
  
  html = html + |RECURSO(S):|
  While Not doc Is Nothing
   html = html + Me.getRecurso(doc)
   Set doc = col.GetNextDocument(doc)
  Wend
  getAllRecursos = html
 End Function

Source Code:

Use "DocumentEntry"
%REM
 Class SortCollection
 Description: Comments for Class
 Atualizado no dia 2, de Agosto de 2010.
%END REM
Class SortCollection
 Private col As NotesDocumentCollection
 Private db As NotesDatabase
 Private index As Integer 
 Private campos() As String
 Private documentEntries() As DocumentEntry
 Private order As String
 
 
%REM
  Sub New
  Description: Comments for Sub
%END REM
 Sub New(col As NotesDocumentCollection, dbOfCollection As NotesDatabase)
  Set Me.col = col
  Set Me.db = dbOfCollection
  Me.order = "[ASCENDING]"
  Redim campos(0)
  
 End Sub
 
%REM
  Sub setOrder
  Description: Comments for Sub
%END REM
 Sub setOrder(order As String)
  Me.order = order
 End Sub
 
%REM
     Sub addCampo
     Description: Comments for Function
%END REM
 Public Sub addCampo(nome As String) 
  campos(nextPosition) = nome 
 End Sub 
 
%REM
     Function nextPosition
     Description: Comments for Function
%END REM
 Private Function nextPosition As Integer 
  Redim Preserve campos(index) 
  nextPosition = index 
  index = index + 1 
 End Function 
 
%REM
     Function Sort
     Description: Comments for Function
%END REM
 Public Function Sort As NotesDocumentCollection
  If col.Count > 0 And campos(0) <> "" Then
   Dim colSorted As NotesDocumentCollection
   
   Call instanceAllEntries
   Call sortAllEntries
   Set colSorted = Me.getEmptyCollection
   
   Dim i As Double
   For i = 0 To Ubound(documentEntries)
    Call colSorted.Adddocument(documentEntries(i).Document)
   Next
   Set col = colSorted
  End If
  Set Sort = col
 End Function
 
%REM
     Function getCollection
     Description: Comments for Function
%END REM
 Public Function getCollection As NotesDocumentCollection
  Set getCollection = col
 End Function
 
%REM
     Sub instanceAllEntries
     Description: Comments for Sub
%END REM
 Private Sub instanceAllEntries
  Redim documentEntries(col.Count - 1)
  
  Dim contador As Integer
  Dim doc As NotesDocument
  
  Set doc = col.Getfirstdocument()
  While Not doc Is Nothing
   Set documentEntries(contador) = New DocumentEntry(doc.Universalid,db)
   Set doc = col.Getnextdocument(doc)
   contador = contador + 1
  Wend
 End Sub
 
%REM
     Sub sortAllEntries
     Description: Comments for Sub
%END REM
 Private Sub sortAllEntries  
  Call quickSort(0, Ubound(documentEntries))
 End Sub
 
%REM
     Sub quickSort
     Description: Comments for Sub
%END REM
 Private Sub quickSort(inicio As Double, fim As Double)  
  Dim i As Double
  Dim k As Double
  
  i = inicio
  k = fim
  
  If (fim - inicio >= 1) Then
   Dim pivo As DocumentEntry
   Set pivo = documentEntries(inicio)
   While (k > i)
    While (pivo.compareTo(documentEntries(i), order, campos) >= 0 And i <= fim And k > i)
     i = i + 1
    Wend
    While (pivo.compareTo(documentEntries(k), order, campos) = -1 And k >= inicio And k >= i)
     k = k - 1
    Wend    
    If (k > i) Then Call swap(i,k)   
   Wend
   
   Call swap(inicio, k)
   Call quickSort(inicio, k - 1)
   Call quickSort(k + 1, fim) 
  End If
  
 End Sub
 
%REM
     Sub swap
     Description: Comments for Sub
%END REM
 Private Sub swap(i As Double, j As Double)
  Dim entryAux As DocumentEntry
  
  Set entryAux = documentEntries(i)
  Set documentEntries(i) = documentEntries(j)
  Set documentEntries(j) = entryAux 
  Exit Sub
 End Sub
 
 
%REM
     Function getEmptyCollection
     Description: Comments for Function
%END REM
 Public Function getEmptyCollection As NotesDocumentCollection
  Set getEmptyCollection = db.GetProfileDocCollection("FelipeRotilho13") 
 End Function
End Class

Compare Documents

2010-07-29T23:26:00.007-03:00

Exemplo de Uso:

Dim i As Double
 Private Sub quickSort(inicio As Double, fim As Double)  
  Dim i As Double
  Dim k As Double
  
  i = inicio
  k = fim
  
  If (fim - inicio >= 1) Then
   Dim pivo As DocumentEntry
   Set pivo = documentEntries(inicio)
   While (k > i)
    While (pivo.compareTo(documentEntries(i), order, campos) >= 0 And i <= fim And k > i)
     i = i + 1
    Wend
    While (pivo.compareTo(documentEntries(k), order, campos) = -1 And k >= inicio And k >= i)
     k = k - 1
    Wend    
    If (k > i) Then Call swap(i,k)   
   Wend
   
   Call swap(inicio, k)
   Call quickSort(inicio, k - 1)
   Call quickSort(k + 1, fim) 
  End If
  
 End Sub

Source Code:

Use "Sort"
%REM
 Class DocumentEntry
 Description: Comments for Class
 Atualizado no dia 2, de Agosto de 2010.
%END REM
Class DocumentEntry
 Private UNID As String
 Private db As NotesDatabase
 %REM
  Sub New
  Description: Comments for Sub
 %END REM
 Sub New(UNID As String, dbOfDocument As NotesDatabase)
  If Len(UNID) = 32 Then
   Me.UNID = UNID
   Set Me.db = dbOfDocument
  Else
   Error 4091, "Invalid Universal ID"
  End If
 End Sub
  
 %REM
  Function Document
  Description: Comments for Function
 %END REM
 Public Function Document As NotesDocument
  Set Document = db.GetDocumentByUNID(UNID)
 End Function
  
 %REM
  Function compareTo
  Description: Comments for Function
 %END REM
 Public Function compareTo(documentEntry As DocumentEntry, order As String, campos As Variant) As Integer
  compareTo = Compare(Me,documentEntry,LBound(campos), order, campos)
 End Function
  
 %REM
  Function Compare
  Description: Comments for Function
 %END REM
 Private Function Compare(arg1 As DocumentEntry, arg2 As DocumentEntry, index As Integer, order As String,  campos As Variant) As Integer
  Dim campo1 As String
  Dim campo2 As String
  campo1 = arg1.getNthFieldValue(index,campos)
  campo2 = arg2.getNthFieldValue(index,campos)
  If campo1 = campo2 Then
   If index = UBound(campos) Then
    Compare = 0
   Else
    Compare = Compare(arg1,arg2,index + 1, order, campos)
   End If
  Else
   Dim s As New Sort(Split(campo1 + "&&&" + campo2,"&&&"))
   Call s.setOrder(order)
   Dim sorted As Variant
   sorted = s.Sort()
   If ArrayGetIndex(sorted,campo1) = 0 Then
    Compare = -1
   Else
    Compare = 1
   End If
  End If
 End Function
  
 %REM
 Function getNthFieldValue
 Description: Comments for Function
 %END REM
 Public Function getNthFieldValue(index As Integer,  campos As Variant) As String
  getNthFieldValue = Me.Document().Getitemvalue(campos(index))(0)
 End Function
  
End Class

Sorting String Array

2010-07-29T20:20:00.005-03:00

%REM  
Class Sort   
 Description: Comments for Class v0.3
 Atualizado no dia 1, de Agosto de 2010.
%END REM 
Class Sort
 Private Vector As Variant
 Private order As String
 Sub New(forSort As Variant)
  Me.Vector = forSort
  order = "[ASCENDING]"
 End Sub
 
 'Deprecated
 Public Function getSortedVector As Variant
  getSortedVector = Sort
 End Function
 
 Public Function Sort As Variant
  Dim varTemp As Variant
   
  If Not IsEmpty(Vector) Then              
   varTemp = Join(Vector,|":"|)
   varTemp = Evaluate(|@Sort("|+ varTemp + |"; | + order + |)|)
   
   Sort = varTemp
  Else
   Sort = Vector
  End If
 End Function
 
 Public Sub setOrder(order As String)
  Me.order = order
 End Sub
End Class